~ [ source navigation ] ~ [ diff markup ] ~ [ identifier search ] ~ [ freetext search ] ~ [ file search ] ~

Linux Cross Reference
Linux/arch/m68k/vmlinux-sun3.lds

Version: ~ [ 2.4.0 ] ~
Architecture: ~ [ i386 ] ~ [ alpha ] ~ [ m68k ] ~ [ mips ] ~ [ ppc ] ~ [ sparc ] ~ [ sparc64 ] ~ 
  1 /* ld script to make m68k Linux kernel */
  2 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
  3 OUTPUT_ARCH(m68k)
  4 ENTRY(_start)
  5 SECTIONS
  6 {
  7   . = 0xE004000;
  8   _text = .;                    /* Text and read-only data */
  9   .text : {
 10         *(.head)
 11         *(.text)
 12         *(.fixup)
 13         *(.text.lock)           /* out-of-line lock text */
 14         *(.gnu.warning)
 15         } = 0x4e75
 16   .kstrtab : { *(.kstrtab) }
 17 
 18 
 19   _etext = .;                   /* End of text section */
 20 
 21   .data : {                     /* Data */
 22         *(.rodata)
 23         *(.data)
 24         CONSTRUCTORS
 25         . = ALIGN(16);          /* Exception table */
 26         __start___ex_table = .;
 27         *(__ex_table) 
 28         __stop___ex_table = .;
 29         __start___ksymtab = .;  /* Kernel symbol table */
 30         *(__ksymtab) 
 31         __stop___ksymtab = .;
 32         }
 33   /* End of data goes *here* so that freeing init code works properly. */
 34   _edata = .;
 35 
 36   . = ALIGN(8192);      /* Init code and data */
 37 __init_begin = .;
 38         .text.init : { *(.text.init) }
 39         .data.init : { *(.data.init) }
 40         . = ALIGN(16);
 41         __setup_start = .;
 42         .setup.init : { *(.setup.init) }
 43         __setup_end = .;
 44         __initcall_start = .;
 45         .initcall.init : { *(.initcall.init) }
 46         __initcall_end = .;
 47         . = ALIGN(8192);
 48         __init_end = .;
 49         .init.task : { *(init_task) }
 50         
 51 
 52   .bss : { *(.bss) }            /* BSS */
 53 
 54   _end = . ;
 55 
 56   .crap : {
 57         /* Stabs debugging sections.  */
 58         *(.stab)
 59         *(.stabstr)
 60         *(.stab.excl)
 61         *(.stab.exclstr)
 62         *(.stab.index)
 63         *(.stab.indexstr)
 64         *(.comment)
 65         *(.note)
 66   }
 67 
 68 }
~ [ source navigation ] ~ [ diff markup ] ~ [ identifier search ] ~ [ freetext search ] ~ [ file search ] ~
This page was automatically generated by the LXR engine.
Visit the LXR main site for more information.