1 /* ld script to make m68k Linux kernel */
2 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
3 OUTPUT_ARCH(m68k)
4 ENTRY(_start)
5 SECTIONS
6 {
7 . = 0x1000;
8 _text = .; /* Text and read-only data */
9 .text : {
10 *(.text)
11 *(.fixup)
12 *(.text.lock) /* out-of-line lock text */
13 *(.gnu.warning)
14 } = 0x4e75
15 .rodata : { *(.rodata) }
16 .kstrtab : { *(.kstrtab) }
17
18 . = ALIGN(16); /* Exception table */
19 __start___ex_table = .;
20 __ex_table : { *(__ex_table) }
21 __stop___ex_table = .;
22
23 __start___ksymtab = .; /* Kernel symbol table */
24 __ksymtab : { *(__ksymtab) }
25 __stop___ksymtab = .;
26
27 _etext = .; /* End of text section */
28
29 .data : { /* Data */
30 *(.data)
31 CONSTRUCTORS
32 }
33
34 .bss : { *(.bss) } /* BSS */
35
36 . = ALIGN(16);
37 .data.cacheline_aligned : { *(.data.cacheline_aligned) }
38
39 _edata = .; /* End of data section */
40
41 . = ALIGN(4096); /* Init code and data */
42 __init_begin = .;
43 .text.init : { *(.text.init) }
44 .data.init : { *(.data.init) }
45 . = ALIGN(16);
46 __setup_start = .;
47 .setup.init : { *(.setup.init) }
48 __setup_end = .;
49 __initcall_start = .;
50 .initcall.init : { *(.initcall.init) }
51 __initcall_end = .;
52 . = ALIGN(8192);
53 __init_end = .;
54
55 init_task : { *(init_task) } /* The initial task and kernel stack */
56
57 _end = . ;
58
59 /* Stabs debugging sections. */
60 .stab 0 : { *(.stab) }
61 .stabstr 0 : { *(.stabstr) }
62 .stab.excl 0 : { *(.stab.excl) }
63 .stab.exclstr 0 : { *(.stab.exclstr) }
64 .stab.index 0 : { *(.stab.index) }
65 .stab.indexstr 0 : { *(.stab.indexstr) }
66 .comment 0 : { *(.comment) }
67 }
This page was automatically generated by the
LXR engine.
Visit the LXR main site for more
information.