1 /* $Id: winmacro.h,v 1.22 2000/05/09 17:40:15 davem Exp $
2 * winmacro.h: Window loading-unloading macros.
3 *
4 * Copyright (C) 1995 David S. Miller (davem@caip.rutgers.edu)
5 */
6
7 #ifndef _SPARC_WINMACRO_H
8 #define _SPARC_WINMACRO_H
9
10 #include <linux/config.h>
11 #include <asm/ptrace.h>
12 #include <asm/psr.h>
13
14 /* These are just handy. */
15 #define _SV save %sp, -REGWIN_SZ, %sp
16 #define _RS restore
17
18 #define FLUSH_ALL_KERNEL_WINDOWS \
19 _SV; _SV; _SV; _SV; _SV; _SV; _SV; \
20 _RS; _RS; _RS; _RS; _RS; _RS; _RS;
21
22 /* Store the register window onto the 8-byte aligned area starting
23 * at %reg. It might be %sp, it might not, we don't care.
24 */
25 #define STORE_WINDOW(reg) \
26 std %l0, [%reg + RW_L0]; \
27 std %l2, [%reg + RW_L2]; \
28 std %l4, [%reg + RW_L4]; \
29 std %l6, [%reg + RW_L6]; \
30 std %i0, [%reg + RW_I0]; \
31 std %i2, [%reg + RW_I2]; \
32 std %i4, [%reg + RW_I4]; \
33 std %i6, [%reg + RW_I6];
34
35 /* Load a register window from the area beginning at %reg. */
36 #define LOAD_WINDOW(reg) \
37 ldd [%reg + RW_L0], %l0; \
38 ldd [%reg + RW_L2], %l2; \
39 ldd [%reg + RW_L4], %l4; \
40 ldd [%reg + RW_L6], %l6; \
41 ldd [%reg + RW_I0], %i0; \
42 ldd [%reg + RW_I2], %i2; \
43 ldd [%reg + RW_I4], %i4; \
44 ldd [%reg + RW_I6], %i6;
45
46 /* Loading and storing struct pt_reg trap frames. */
47 #define LOAD_PT_INS(base_reg) \
48 ldd [%base_reg + REGWIN_SZ + PT_I0], %i0; \
49 ldd [%base_reg + REGWIN_SZ + PT_I2], %i2; \
50 ldd [%base_reg + REGWIN_SZ + PT_I4], %i4; \
51 ldd [%base_reg + REGWIN_SZ + PT_I6], %i6;
52
53 #define LOAD_PT_GLOBALS(base_reg) \
54 ld [%base_reg + REGWIN_SZ + PT_G1], %g1; \
55 ldd [%base_reg + REGWIN_SZ + PT_G2], %g2; \
56 ldd [%base_reg + REGWIN_SZ + PT_G4], %g4; \
57 ldd [%base_reg + REGWIN_SZ + PT_G6], %g6;
58
59 #define LOAD_PT_YREG(base_reg, scratch) \
60 ld [%base_reg + REGWIN_SZ + PT_Y], %scratch; \
61 wr %scratch, 0x0, %y;
62
63 #define LOAD_PT_PRIV(base_reg, pt_psr, pt_pc, pt_npc) \
64 ld [%base_reg + REGWIN_SZ + PT_PSR], %pt_psr; \
65 ld [%base_reg + REGWIN_SZ + PT_PC], %pt_pc; \
66 ld [%base_reg + REGWIN_SZ + PT_NPC], %pt_npc;
67
68 #define LOAD_PT_ALL(base_reg, pt_psr, pt_pc, pt_npc, scratch) \
69 LOAD_PT_YREG(base_reg, scratch) \
70 LOAD_PT_INS(base_reg) \
71 LOAD_PT_GLOBALS(base_reg) \
72 LOAD_PT_PRIV(base_reg, pt_psr, pt_pc, pt_npc)
73
74 #define STORE_PT_INS(base_reg) \
75 std %i0, [%base_reg + REGWIN_SZ + PT_I0]; \
76 std %i2, [%base_reg + REGWIN_SZ + PT_I2]; \
77 std %i4, [%base_reg + REGWIN_SZ + PT_I4]; \
78 std %i6, [%base_reg + REGWIN_SZ + PT_I6];
79
80 #define STORE_PT_GLOBALS(base_reg) \
81 st %g1, [%base_reg + REGWIN_SZ + PT_G1]; \
82 std %g2, [%base_reg + REGWIN_SZ + PT_G2]; \
83 std %g4, [%base_reg + REGWIN_SZ + PT_G4]; \
84 std %g6, [%base_reg + REGWIN_SZ + PT_G6];
85
86 #define STORE_PT_YREG(base_reg, scratch) \
87 rd %y, %scratch; \
88 st %scratch, [%base_reg + REGWIN_SZ + PT_Y];
89
90 #define STORE_PT_PRIV(base_reg, pt_psr, pt_pc, pt_npc) \
91 st %pt_psr, [%base_reg + REGWIN_SZ + PT_PSR]; \
92 st %pt_pc, [%base_reg + REGWIN_SZ + PT_PC]; \
93 st %pt_npc, [%base_reg + REGWIN_SZ + PT_NPC];
94
95 #define STORE_PT_ALL(base_reg, reg_psr, reg_pc, reg_npc, g_scratch) \
96 STORE_PT_PRIV(base_reg, reg_psr, reg_pc, reg_npc) \
97 STORE_PT_GLOBALS(base_reg) \
98 STORE_PT_YREG(base_reg, g_scratch) \
99 STORE_PT_INS(base_reg)
100
101 #define SAVE_BOLIXED_USER_STACK(cur_reg, scratch) \
102 ld [%cur_reg + AOFF_task_thread + AOFF_thread_w_saved], %scratch; \
103 sll %scratch, 2, %scratch; \
104 add %scratch, %cur_reg, %scratch; \
105 st %sp, [%scratch + AOFF_task_thread + AOFF_thread_rwbuf_stkptrs]; \
106 sub %scratch, %cur_reg, %scratch; \
107 sll %scratch, 4, %scratch; \
108 add %scratch, %cur_reg, %scratch; \
109 STORE_WINDOW(scratch + AOFF_task_thread + AOFF_thread_reg_window); \
110 sub %scratch, %cur_reg, %scratch; \
111 srl %scratch, 6, %scratch; \
112 add %scratch, 1, %scratch; \
113 st %scratch, [%cur_reg + AOFF_task_thread + AOFF_thread_w_saved];
114
115 #ifdef CONFIG_SMP
116 #define LOAD_CURRENT4M(dest_reg, idreg) \
117 rd %tbr, %idreg; \
118 sethi %hi(C_LABEL(current_set)), %dest_reg; \
119 srl %idreg, 10, %idreg; \
120 or %dest_reg, %lo(C_LABEL(current_set)), %dest_reg; \
121 and %idreg, 0xc, %idreg; \
122 ld [%idreg + %dest_reg], %dest_reg;
123
124 /* Sliiick. We have a Linux current register :) -jj */
125 #define LOAD_CURRENT4D(dest_reg) \
126 lda [%g0] ASI_M_VIKING_TMP2, %dest_reg;
127
128 /* Blackbox - take care with this... - check smp4m and smp4d before changing this. */
129 #define LOAD_CURRENT(dest_reg, idreg) \
130 sethi %hi(___b_load_current), %idreg; \
131 sethi %hi(C_LABEL(current_set)), %dest_reg; \
132 sethi %hi(C_LABEL(boot_cpu_id4)), %idreg; \
133 or %dest_reg, %lo(C_LABEL(current_set)), %dest_reg; \
134 ldub [%idreg + %lo(C_LABEL(boot_cpu_id4))], %idreg; \
135 ld [%idreg + %dest_reg], %dest_reg;
136 #else
137 #define LOAD_CURRENT(dest_reg, idreg) \
138 sethi %hi(C_LABEL(current_set)), %idreg; \
139 ld [%idreg + %lo(C_LABEL(current_set))], %dest_reg;
140 #endif
141
142 #endif /* !(_SPARC_WINMACRO_H) */
143
This page was automatically generated by the
LXR engine.
Visit the LXR main site for more
information.